¿Eres un usuario experimentado de Google Sheets? Entonces probablemente sepas cómo enlazar datos entre varias hojas de cálculo y utilices la función IMPORTRANGE para ello. Mientras tanto, podrías convertirte en un experto y hacerlo mejor. Los profesionales combinan IMPORTRANGE con QUERY y manipulan el conjunto de datos importado al mismo tiempo. Si quieres unirte a los expertos y mejorar tus habilidades en Google Sheets – bienvenido a esta entrada del blog.
Explicación de la función IMPORTRANGE
La función IMPORTRANGE permite importar un rango de datos de una hoja de cálculo especificada.
Sintaxis IMPORTRANGE
=IMPORTRANGE("hoja_de_calculo_url", "rango_cadena")
spreadsheet_url– inserta la URL de la hoja de cálculo desde la que importar los datos. Por ejemplo
https://docs.google.com/spreadsheets/d/1h3pPtbMAsPM_jS2wMLG_GflqyAd
También puedes utilizar el ID de la hoja de cálculo en lugar de la URL completa:
1h3pPtbMAsPM_jS2wMLG_GflqyAd
range_string– inserta una cadena que especifique el rango de datos para la importación. Por ejemplo,Hoja1!A1:C13. range_string consta delnombre_de_la_hojay delrango.rango– especifica el rango de celdas a importar.nombre_hoja– especifica este parámetro si no vas a importar datos de la primera hoja del documento.
Ejemplo de fórmula IMPORTRANGE
Tenemos una base de datos en la hoja de cálculo llamada Pedidos de Airtable. Vamos a importar todos los valores en las columnas E a I. Aquí está la fórmula para esto:
=IMPORTRANGE("https://docs.google.com/spreadsheets/d/1PuEsRXSShgbBKiz-6uxP6OGeS9kBHW0d-rpUAaMl2_g/edit?usp=sharing", "¡Todos los pedidos!E1:I21")
Puedes consultar el ejemplo de fórmula en esta ficha.
Consulta nuestro tutorial de Google IMPORTRANGE para obtener más información.
Explicación de la función QUERY
La función QUERY permite manipular datos mientras los importa de otra hoja. Puede seleccionar, filtrar, ordenar y realizar otras manipulaciones.
Sintaxis de QUERY
= QUERY(rango_datos, "cadena_consulta")
data_range– inserta un rango de celdas para consultar.data_rangepuede incluir columnas con valores booleanos, numéricos o de cadena. Si una columna contiene diferentes tipos de datos, QUERY elegirá el tipo de datos mayoritario como tipo de dato de la columna.
query_string– inserta una cadena hecha usando cláusulas del Lenguaje de Consulta de la API de Google. Como alternativa, puedes hacer referencia a una celda que contengaquery_string(en este caso, evita las comillas dobles tanto en la fórmula QUERY como enquery_string).
Opcionalmente, puedes ampliar la fórmula QUERY con una parte que defina el número de cabeceras de su rango de datos. En este caso, la sintaxis de QUERY será la siguiente:
= QUERY(rango_datos, "cadena_consulta",número_cabeceras)
Ejemplo de fórmula QUERY
Utilicemos el rango de datos que importamos utilizando IMPORTRANGE en el ejemplo anterior y hagamos las siguientes manipulaciones:
- Selecciona las columnas A, D y E.
- Filtra los productos con un precio total superior a 50 €.
- Ordena el resultado por cantidad en orden ascendente.
- Cambia el encabezado de la columna A de “Producto” a “Nombre del bocadillo”.
Aquí está la fórmula QUERY para hacerlo:
=QUERY('IMPORTRANGE ejemplo'!A:E, "select A,D,E where E>50 order by D label A 'Nombre del sandwich'")
Puede consultar el ejemplo de fórmula en esta ficha.
Aunque QUERY es una función potente, tiene un inconveniente: sólo funciona dentro de una hoja de cálculo. Por lo tanto, puedes pasar datos de una hoja a otra, pero no puedes consultar otra hoja de cálculo. La combinación de QUERY+IMPORTRANGE está pensada para solucionar este problema.
Ya hablamos de esta función en el blog “Google Sheets Query“.
Utilización conjunta de QUERY e IMPORTRANGE
Cuando se aplican conjuntamente QUERY e IMPORTRANGE, se puede consultar un rango de datos en otra hoja de cálculo (o en varias hojas de cálculo).
Si necesitas una visión rápida del uso de QUERY+IMPORTRANGE, echa un vistazo a esta parte del videotutorial IMPORTRANGE de Railsware Product Academy. El timestamp necesario ya está configurado:)
Sintaxis QUERY+IMPORTRANGE
=QUERY(IMPORTRANGE("spreadsheet_url", "data_range"), "query_string")
spreadsheet_url– inserta la URL de la hoja de cálculo desde la que importar los datos.data_range– inserta un rango de celdas para consultar.query_string– inserta una cadena realizada utilizando cláusulas del Lenguaje de consulta de la API de Google.
Opcionalmente, puedes ampliar la fórmula con una parte que defina el número de cabeceras de tu rango de datos. En este caso, la sintaxis será la siguiente:
=QUERY(IMPORTRANGE("spreadsheet_url", "data_range"), "query_string", [headers])
Por defecto se utiliza una línea de cabecera.
Ejemplo de fórmula QUERY+IMPORTRANGE
Repitamos los ejemplos anteriores, pero utilizando una sola fórmula. Entonces, necesitamos
- importar un conjunto de datos de la hoja de cálculo llamado Pedidos de Airtable.
- hacer algunas manipulaciones con él:
- Seleccionar las columnas A, D y E.
- Filtrar los productos con un precio total superior a 50 €.
- Ordenar el resultado por cantidad en orden ascendente
- Cambiar el encabezado de la columna A de “Producto” a “Nombre sandwich”.
Esta es la fórmula:
=QUERY(IMPORTRANGE("https://docs.google.com/spreadsheets/d/1PuEsRXSShgbBKiz-6uxP6OGeS9kBHW0d-rpUAaMl2_g/edit?usp=sharing", "¡Todos los pedidos!E1:I21"),
"select Col1,Col4,Col5 where Col5>50 order by Col4 label Col1 'Nombre sandwich'")
E1:I21 es nuestro rango de datos de destino. Durante la importación, la referencia de la columna cambiará de la siguiente manera:
E a A, o simplemente Columna #1 – Col1
F a B, o simplemente Columna #2 – Col2
G a C, o simplemente Columna #3 – Col3
H a D, o simplemente Columna #4 – Col4
I a E, o simplemente Columna #5 – Col5
Por eso recomendamos que apliques la referencia Col en sus fórmulas QUERY para evitar errores.
Puedes consultar el ejemplo de fórmula en esta ficha.
Cómo consultar datos de otras hojas de cálculo sin fórmulas
El uso de fórmulas complejas de QUERY e IMPORTRANGE puede llevar demasiado tiempo, por no hablar de los posibles errores de sintaxis, combinados con los problemas de Google.
Afortunadamente, existe una solución alternativa. Con Coupler.io puedes consultar tu rango de datos desde otras hojas de cálculo o incluso fuentes de datos externas sin necesidad de fórmulas complejas. Es más, te permite automatizar la importación de datos desde varias hojas de cálculo a un único documento.
De este modo, ahorrarás horas de tiempo al mes, evitarás posibles errores y tendrás tus datos constantemente actualizados.
Utiliza el siguiente formulario para comprobarlo. Hemos preseleccionado Google Sheets como fuente, pero eres libre de seleccionar tu opción en el siguiente formulario. Haz clic en Continuar y regístrate gratis con tu cuenta de Google.
Veamos cómo se pueden consultar los datos de la hoja de cálculo llamada Pedidos desde Airtable tal y como hicimos en el ejemplo anterior.
Elige Pedidos de Airtable como archivo de origen. A continuación, especifica la hoja – Todos los pedidos – para la transferencia de datos. Opcionalmente, puedes seleccionar un rango particular que te gustaría exportar.
Continúa con el siguiente paso, donde podrás transformar o consultar tus datos. Haz clic en Gestión de columnas y desmarca las columnas excepto A, D y E. De este modo, ocultarás sobre la marcha las columnas innecesarias.
Puedes utilizar el filtrado y otras opciones de consulta. Haz clic en Filtro para filtrar los productos con un precio total superior a 50 dólares. Selecciona una columna llamada Precio total, especifica la condición “más de” e introduce 50 en el campo de valor.
Haz clic en el botón Ordenar, selecciona la columna Cantidad y elige orden ascendente.
Para cambiar el encabezado de la columna A de “Producto” a “Nombre sandwich”, haz clic en las tres líneas junto al nombre de la columna y selecciona Editar columna.
Una vez transformados los datos, procede a la configuración del destino de tus datos. Tendrás que elegir el archivo y la hoja donde importar los datos consultados. Finalmente, haz clic en Ejecutar importador.
Ahora ya tienes tus datos disponibles en la hoja de cálculo de destino:
Si lo deseas, activa la actualización automática de datos y establece un calendario de actualizaciones.
Automatice la exportación de datos con Coupler.io
Empiece gratisQué puedes hacer con las funciones IMPORTRANGE + QUERY (ejemplos de fórmulas de la vida real)
Ahora, vamos a descubrir lo que una combinación de IMPORTRANGE y QUERY puede proporcionar. Los pedidos de Airtable serán nuestra hoja de cálculo fuente de datos. Todo lo demás es la magia de las cláusulas del lenguaje QUERY.
Importar un rango específico de datos con la cláusula QUERY select
La cláusula QUERY select permite elegir exactamente las columnas que deseas extraer. Más información sobre Google Sheets Query: Select.
Tarea:
- Importa las columnas B, E, H e I de la hoja de cálculo Pedidos de Airtable.
Ejemplo de fórmula QUERY+IMPORTRANGE
=QUERY(IMPORTRANGE("https://docs.google.com/spreadsheets/d/1PuEsRXSShgbBKiz-6uxP6OGeS9kBHW0d-rpUAaMl2_g/edit?usp=sharing", "¡Todos los pedidos!A:I"), "select Col2,Col5,Col8,Col9")
Puedes consultar el ejemplo de fórmula en esta ficha.
Combinar datos de varias hojas con QUERY e IMPORTRANGE
Ahora bien, lo más probable es que tengas datos en varias hojas y quieras fusionar cierta información en una sola hoja. No hay problema. También puedes utilizar QUERY e IMPORTRANGE con varias hojas.
Para ello, utiliza la misma estructura que antes. Sin embargo, tendrás que encerrar varias funciones IMPORTRANGE entre llaves {} y separarlas mediante comas (para combinar datos horizontalmente) o punto y coma (para combinar datos verticalmente).
Sintaxis de fórmula QUERY + IMPORTRANGE para combinar hojas de cálculo horizontalmente:
=QUERY({IMPORTRANGE("spreadsheet1_url", "data_range"),IMPORTRANGE("spreadsheet2_url", "data_range"),IMPORTRANGE("spreadsheet3_url", "data_range"),..}, "query_string")
Sintaxis de fórmula QUERY + IMPORTRANGE para combinar hojas de cálculo verticalmente:
=QUERY({IMPORTRANGE("spreadsheet1_url"; "data_range"),IMPORTRANGE("spreadsheet2_url"; "data_range"),IMPORTRANGE("spreadsheet3_url"; "data_range");..}, "query_string")
data_range debe contener el mismo rango de columnas para cada spreadsheet_url, mientras que el número de filas puede diferir.
IMPORTANTE: Antes de importar datos desde múltiples hojas con QUERY e IMPORTRANGE, tendrás que hacer importaciones de datos desde cada hoja de cálculo por separado para permitir el acceso. De lo contrario, obtendrás #¡VALOR! Error: en ARRAY_LITERAL, faltaban valores para una o más filas.
La razón es muy sencilla: cuando IMPORTAS datos de una hoja de cálculo concreta utilizando IMPORTRANGE por primera vez, la fórmula solicita permitir el acceso: es necesario hacer clic en un pequeño botón que aparece desde la celda.
Pero no existe tal botón cuando lo haces para varias fuentes. Echa un vistazo a nuestra entrada de blog Por qué IMPORTRANGE no está funcionando para manejar otros errores.
Tarea:
- Importa las columnas B, E, H e I de la hoja de cálculo#1, Pedidos de Airtable.
- Importa las columnas B, E, H e I de la hoja de cálculo#2, Pedidos de Airtable#2.
- Importa las columnas B, E, H e I de la hoja de cálculo#3, Pedidos de Airtable#3.
- Omite la primera fila al exportar los datos de las hojas de cálculo nº 2 y nº 3.
Ejemplo de fórmula QUERY+IMPORTRANGE
=QUERY({IMPORTRANGE("1PuEsRXSShgbBKiz-6uxP6OGeS9kBHW0d-rpUAaMl2_g", "¡Todos los pedidos!A1:I21"); IMPORTRANGE("1z2yS9uY5Zpp01qZ_opbaO7SnnehS9rknAZlJozXA7G4", "¡Todos los pedidos!A2:I21"); IMPORTRANGE("1iUwZDui3Q6mBpswPuU7e9NdvKwNGRA9A3JAhqFDMFbk", "¡Todos los pedidos!A2:I21")},
"select Col2,Col5,Col8,Col9")
Una vez que permitimos el acceso a la hoja de cálculo final, nuestra fórmula para múltiples fuentes funcionó inmediatamente.
Puedes consultar el ejemplo de fórmula en esta ficha.
Recorta las filas innecesarias de los datos importados con las cláusulas QUERY limit y offset
La cláusula limit QUERY permite definir el número total de filas (excluyendo la cabecera) que se importarán. La cláusula offset QUERY permite definir cuántas filas se cortarán de la parte superior del rango de datos importado. Obtén más información sobre Google Sheets Query: Límite y Desplazamiento.
Tarea nº 1:
- Importa las columnas B, E, H e I de la hoja de cálculo Pedidos de Airtable.
- Reduce el número de filas importadas a 10 (excluida la cabecera).
Ejemplo de fórmula QUERY+IMPORTRANGE:
=QUERY(IMPORTRANGE("https://docs.google.com/spreadsheets/d/1PuEsRXSShgbBKiz-6uxP6OGeS9kBHW0d-rpUAaMl2_g/edit?usp=sharing", "¡Todos los pedidos!A:I"), "select Col2,Col5,Col8,Col9 Limit 10")
Puedes consultar el ejemplo de fórmula en esta ficha.
Tarea nº 2:
- Importa las columnas B, E, H e I de la hoja de cálculo Pedidos de Airtable.
- Reduce el número de filas importadas a 10 (excluida la cabecera).
- Saltar cinco filas desde la parte superior de la hoja de cálculo de la que exportamos los datos (excluyendo la cabecera).
Ejemplo de fórmula QUERY+IMPORTRANGE:
=QUERY(IMPORTRANGE("https://docs.google.com/spreadsheets/d/1PuEsRXSShgbBKiz-6uxP6OGeS9kBHW0d-rpUAaMl2_g/edit?usp=sharing", "¡Todos los pedidos!A:I"), "select Col2,Col5,Col8,Col9 Limit 10 offset 5 ")
Puedes consultar el ejemplo de fórmula en esta ficha.
Cambiar los nombres de las columnas importadas con la cláusula QUERY etiqueta
La cláusula QUERY etiquetas permite cambiar los nombres de las columnas (cabeceras). Más información sobre Google Sheets Query: Etiqueta.
Tarea:
- Importa las columnas B, E, H e I de la hoja de cálculo Pedidos de Airtable.
- Reduce el número de filas importadas a 10 (excluida la cabecera).
- Cambia el nombre de las cabeceras de las columnas importadas:
- Fecha del pedido => Hora
- Producto => Bocadillo
- Cantidad => Cuántos
- Precio total => Cuánto
Ejemplo de fórmula QUERY+IMPORTRANGE
=QUERY(IMPORTRANGE("https://docs.google.com/spreadsheets/d/1PuEsRXSShgbBKiz-6uxP6OGeS9kBHW0d-rpUAaMl2_g/edit?usp=sharing", "¡Todos los pedidos!A:I"), "select Col2,Col5,Col8,Col9 Limit 10 label Col2 'Tiempo', Col5 'Bocadillo', Col8 'Cuántos', Col9 'Cuánto'")
Puedes consultar el ejemplo de fórmula en esta ficha.
Formatea los valores de las columnas importadas con la cláusula QUERY format
La cláusula QUERY format permite aplicar formatos específicos a columnas importadas. Más información sobre Google Sheets Query: Formato.
Tarea:
- Importa las columnas B, E, H e I de la hoja de cálculo Pedidos de Airtable.
- Reduce el número de filas importadas a 10 (excluida la cabecera).
- Formatea los valores de la columna B para mostrar sólo el mes y el año.
Ejemplo de fórmula QUERY+IMPORTRANGE
=QUERY(IMPORTRANGE("https://docs.google.com/spreadsheets/d/1PuEsRXSShgbBKiz-6uxP6OGeS9kBHW0d-rpUAaMl2_g/edit?usp=sharing", "¡Todos los pedidos!A:I"), "select Col2,Col5,Col8,Col9 Limit 10 format Col2 'mmm-aaaa'")
Puedes consultar el ejemplo de fórmula en esta ficha.
Importa los datos filtrados con la cláusula QUERY where
La cláusula QUERY where permite filtrar las filas de las columnas importadas en función de las condiciones establecidas. Más información sobre Google Sheets Query: Where.
Tarea:
- Importa las columnas B, E, H e I de la hoja de cálculo Pedidos de Airtable.
- Filtra los datos importados por la siguiente condición – el valor de la columna I debe ser mayor o igual a 50.
Ejemplo de fórmula QUERY+IMPORTRANGE
=QUERY(IMPORTRANGE("https://docs.google.com/spreadsheets/d/1PuEsRXSShgbBKiz-6uxP6OGeS9kBHW0d-rpUAaMl2_g/edit?usp=sharing", "¡Todos los pedidos!A:I"), "select Col2,Col5,Col8,Col9 where Col9>=50")
Aplicar criterios múltiples para QUERY e IMPORTRANGE
Siguiendo con el ejemplo anterior, cuando se utiliza la sentencia where no es necesario limitarse a un único criterio. Utilizando operadores como AND u OR puede filtrar por múltiples criterios utilizando QUERY e IMPORTRANGE.
Tarea:
- Filtra la fórmula anterior para obtener también los pedidos cuyo valor en la columna E empiece por la letra “S”.
Ejemplo de fórmula QUERY+IMPORTRANGE
=QUERY(IMPORTRANGE("https://docs.google.com/spreadsheets/d/1PuEsRXSShgbBKiz-6uxP6OGeS9kBHW0d-rpUAaMl2_g/edit?usp=sharing", "¡Todos los pedidos!A:I"), "select Col2,Col5,Col8,Col9 where Col5 starts with 'S' and Col9>=50")
Puedes consultar el ejemplo de fórmula en esta ficha.
Además, también puedes utilizar QUERY e IMPORTRANGE con varios criterios y un operador OR para seleccionar los resultados que cumplan cualquiera de los criterios. Por ejemplo:
=QUERY(IMPORTRANGE("https://docs.google.com/spreadsheets/d/1PuEsRXSShgbBKiz-6uxP6OGeS9kBHW0d-rpUAaMl2_g/edit?usp=sharing", "¡Todos los pedidos!A:I"), "select Col2,Col5,Col8,Col9 where Col5 starts with 'S' or Col9<30")
Buscar datos que contengan una determinada frase utilizando QUERY e IMPORTRANGE
También puedes utilizar la cláusula where para especificar qué debe contener una determinada columna para cumplir sus criterios o qué frase debe evitar al devolver los resultados. Para ello, se utiliza un operador contains.
Tarea:
- Filtrar los datos del pedido para obtener sólo los pedidos con productos que no contengan la palabra “sandwich”.
Ejemplo de fórmula QUERY+IMPORTRANGE:
=QUERY(IMPORTRANGE("https://docs.google.com/spreadsheets/d/1PuEsRXSShgbBKiz-6uxP6OGeS9kBHW0d-rpUAaMl2_g/edit?usp=sharing", "¡Todos los pedidos!A:I"), "select Col2,Col5,Col8,Col9 where Col5 not contains 'sandwich'")
Para buscar datos que contengan una determinada frase en QUERY + IMPORTRANGE, omite la palabra clave not.
Ten en cuenta que la cadena que utilices con contains distingue entre mayúsculas y minúsculas. Si, por ejemplo, tiene tanto ‘Sandwich’ como ‘sandwich’ en la tabla, querrás utilizar los operadores OR o AND para elegir cualquiera de estas versiones, repitiendo toda la sentencia ‘contains’. Por ejemplo:
where Col5 not contains 'sandwich' and Col5 not contains 'Sandwich'
where Col5 contains 'sandwich' or Col5 contains 'Sandwich'
Ordenar los datos importados con la cláusula QUERY order by
La cláusula QUERY order by permite ordenar los datos en función de la columna elegida en orden ascendente/descendente. Más información sobre Google Sheets Query: Ordenar por.
Tarea:
- Importa las columnas B, E, H e I de la hoja de cálculo Pedidos de Airtable.
- Filtra los datos importados por la columna I donde los valores deben ser mayores o iguales a 50.
- Ordena los datos importados por fecha de pedido (columna B) en orden descendente
Ejemplo de fórmula QUERY+IMPORTRANGE
=QUERY(IMPORTRANGE("https://docs.google.com/spreadsheets/d/1PuEsRXSShgbBKiz-6uxP6OGeS9kBHW0d-rpUAaMl2_g/edit?usp=sharing", "¡Todos los pedidos!A:I"), "select Col2,Col5,Col8,Col9 where Col9>=50 order by Col2 DESC")
Puedes consultar el ejemplo de fórmula en esta ficha.
Operaciones aritméticas con los datos importados
Puedes sumar (+), restar (-), multiplicar (*) y dividir (/) columnas de una hoja de cálculo e importar el resultado como una columna independiente. Más información sobre la consulta de Google Sheets: Operadores aritméticos.
Tarea:
- Importa las columnas E e I de la hoja de cálculo Pedidos de Airtable.
- Multiplica el Precio (columna G) por la Cantidad (columna H) e importa el resultado como una columna independiente denominada “Precio total calculado“.
Ejemplo de fórmula QUERY+IMPORTRANGE
=QUERY(IMPORTRANGE("https://docs.google.com/spreadsheets/d/1PuEsRXSShgbBKiz-6uxP6OGeS9kBHW0d-rpUAaMl2_g/edit?usp=sharing", "¡Todos los pedidos!A:I"), "select Col5,Col7*Col8,Col9 label Col7*Col8 'Precio total calculado'")
Puedes consultar el ejemplo de fórmula en esta ficha.
Operaciones de agregación con los datos importados
Dentro de las cláusulas QUERY select, order by, label y format, puedes aplicar las siguientes funciones de agregación a las columnas importadas:
avg()– proporciona la media de todos los números de una columna.sum()– proporciona la suma de todos los números de una columna.count()– proporciona la cantidad de elementos de una columna (las filas con celdas vacías no se calculan).max()– proporciona el valor máximo de una columna.min()– proporciona el valor mínimo de una columna.
Las funciones de agregación no son aplicables a las cláusulas QUERY where, group by, pivot, limit y offset.
Más información sobre Google Sheets Query: Funciones de agregación.
Tarea:
- Importa las columnas B, E, H e I de la hoja de cálculo Pedidos de Airtable.
- Indica el valor mínimo en la columna B.
- Cuenta los elementos de la columna E.
- Indica la suma de todos los números de la columna H.
- Indica la media de todos los valores de la columna I.
Ejemplo de fórmula QUERY+IMPORTRANGE
=QUERY(IMPORTRANGE("https://docs.google.com/spreadsheets/d/1PuEsRXSShgbBKiz-6uxP6OGeS9kBHW0d-rpUAaMl2_g/edit?usp=sharing", "¡Todos los pedidos!A:I"), "select min(Col2),count(Col5),sum(Col8),avg(Col9)")
Puedes consultar el ejemplo de fórmula en esta ficha.
Operaciones escalares con los datos importados
Puedes utilizar funciones escalares para convertir parámetros importados en un único valor. Por ejemplo, si aplicas la función escalar year(), obtendrás el valor del año en el formato AAAA-MM-DD. Más información sobre la consulta de Google Sheets: Funciones escalares.
Tarea:
- Importa las columnas B, E, H e I de la hoja de cálculo Pedidos de Airtable.
- Obtener el día de la semana a partir de los valores de fecha de la columna B.
- Sustituye todas las letras por mayúsculas en la columna E.
- Calcula la diferencia entre la fecha del pedido y la hora actual, e importa los valores en una columna separada denominada “Diferencia horaria en días”.
Ejemplo de fórmula QUERY+IMPORTRANGE
=QUERY(IMPORTRANGE("https://docs.google.com/spreadsheets/d/1PuEsRXSShgbBKiz-6uxP6OGeS9kBHW0d-rpUAaMl2_g/edit?usp=sharing", "¡Todos los pedidos!A:I"), "select dayofweek(Col2),upper(Col5),Col8,Col9,dateDiff(Col2,now()) label dateDiff(Col2,now())'Diferencia de tiempo en días'")
Puedes consultar el ejemplo de fórmula en esta ficha.
Agrega los datos importados a través de las filas con la cláusula QUERY group by
La cláusula QUERY group by permite agrupar valores en el rango de datos seleccionado basándose en una condición específica. La cláusula se puede aplicar si se ha utilizado una función de agregación dentro de la cláusula select. Más información sobre Google Sheets Query: Agrupar por.
Tarea:
- Importa las columnas B, E, H e I de la hoja de cálculo Pedidos de Airtable.
- Resume los datos del precio total (columna I).
- Agrupa los valores agregados por el nombre del Producto (columna E).
- Ordena los datos importados por los valores agrupados (columna E) en orden ascendente.
Ejemplo de fórmula QUERY+IMPORTRANGE
=QUERY(IMPORTRANGE("https://docs.google.com/spreadsheets/d/1PuEsRXSShgbBKiz-6uxP6OGeS9kBHW0d-rpUAaMl2_g/edit?usp=sharing", "¡Todos los pedidos!A:I"), "select Col2,Col5,Col8,sum(Col9) Group by Col5,Col2,Col8 order by Col5")
Puedes consultar el ejemplo de fórmula en esta ficha.
Agrega los datos importados y gira las filas en columnas con la cláusula QUERY pivot
La cláusula QUERY pivot permite convertir filas en columnas, y viceversa, así como agregar, transformar y agrupar datos por cualquier campo. La cláusula se puede aplicar si se ha utilizado una función de agregación dentro de la cláusula select. Más información sobre Google Sheets Query: Pivot.
Tarea:
- Importa las columnas E e I de la hoja de cálculo Pedidos de Airtable.
- Resume los datos del precio total (columna I).
- Pivota los valores agregados por el Nombre del producto (columna E).
Ejemplo de fórmula QUERY+IMPORTRANGE
=QUERY(IMPORTRANGE("https://docs.google.com/spreadsheets/d/1PuEsRXSShgbBKiz-6uxP6OGeS9kBHW0d-rpUAaMl2_g/edit?usp=sharing", "¡Todos los pedidos!A:I"), "select sum(Col9) pivot(Col5)")
Puedes consultar el ejemplo de fórmula en esta ficha.
Prueba la alternativa QUERY e IMPORTRANGE para consultar tus datos sin fórmulas
Bueno, este ha sido un viaje bastante largo, ¡pero lo has conseguido! Ahora ya sabes todo lo que puedes hacer con QUERY e IMPORTRANGE en Google Sheets. Aún así, estas fórmulas pueden no ser fáciles de usar, pueden tomar mucho tiempo y ponerte en riesgo con errores de sintaxis.
Por eso, para casos más avanzados, es mejor adoptar un enfoque sin fórmulas utilizando Coupler.io. Puede ayudarte a consultar tu rango de datos desde otras hojas de cálculo o fuentes externas y cargarlo en la hoja de cálculo necesaria. Así que, pruébalo, y no tendrás que gastar tiempo en fórmulas o recibir #ERROR nunca más ?
